Pannello di Controllo Moderatore ]

[Risolto]Trova mese in data e inserisci specifica cella

Discussioni sull'applicazione per i fogli di calcolo

[Risolto]Trova mese in data e inserisci specifica cella

Messaggioda sandro merlino » sabato 9 giugno 2018, 9:34

Ciao a tutti,
Vi chiedo cortesemente l'aiuto per questo problema che non posso risolvere da giorni
Devo analizzare alcuni dati di ieri quindi oggi()-1
Devo inserire dei valori nel foglio DM nelle celle H126, I126, K126, L126
I valori che devo inserire sono in base al giorno di ieri e questa volta devo prendere il mese in considerazione
Spiego meglio:
Se oggi è il 2/1/2018 devo prendere in considerazione ieri che sarà 1/1/2018. Quindi essendo il mese 01 devo inserire
in H126 il valore contenuto in H122 del foglio V , I126 il valore contenuto in K122 del foglio V, K126 il valore contenuto in N122 del foglio V, L126 il valore contenuto Q122 in del foglio V

Se oggi è il 15/2/2018 devo prendere in considerazione ieri che sarà 14/2/2018. Quindi essendo il mese 02 devo inserire
in H126 il valore contenuto in H222 del foglio V , I126 il valore contenuto in K222 del foglio V, K126 il valore contenuto in N222 del foglio V, L126 il valore contenuto Q222 in del foglio V

fino ad arrivare

Se oggi è il 20/12/2018 devo prendere in considerazione ieri che sarà 19/12/2018. Quindi essendo il mese 12 devo inserire
in H126 il valore contenuto in H1222 del foglio V , I126 il valore contenuto in K1222 del foglio V, K126 il valore contenuto in N1222 del foglio V, L126 il valore contenuto Q1222 in del foglio V

Problemi ci sono in questo ultimo caso

Se oggi è il 1/1/2018 devo prendere in considerazione ieri che sarà 31/12/2017. Quindi essendo il mese 12 dell'ANNO PRECEDENTE devo inserire
in H126 il valore contenuto in N1222 del foglio V , I126 il valore contenuto in Q1222 del foglio V, K126 devo scrivere"NON DISPONIBILE" se la cella Q5 del foglio V è ITALIANO oppure "NOT AVAILABLE" se è INGLESE, L126 devo scrivere"NON DISPONIBILE" se la cella Q5 del foglio V è ITALIANO oppure "NOT AVAILABLE" se è INGLESE

Rimango in attesa per domande se non sono stato chiaro

Grazie 1000

Sandro
Allegati
mese e relativa cella.ods
(164.53 KiB) Scaricato 10 volte
Ultima modifica di sandro merlino il venerdì 22 giugno 2018, 19:18, modificato 1 volta in totale.
openoffice 4.1.1
sandro merlino
 
Messaggi: 432
Iscritto il: giovedì 12 gennaio 2012, 21:33

Re: Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » sabato 16 giugno 2018, 14:46

OK.
In H126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120<>TESTO(ANNO(OGGI()-1);"@");
    INDICE($V.$N$122:$N$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
    INDICE($V.$H$122:$H$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)
)


In I126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120<>TESTO(ANNO(OGGI()-1);"@");
    INDICE($V.$Q$122:$Q$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
    INDICE($V.$K$122:$K$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)
)


In K126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120=TESTO(ANNO(OGGI()-1);"@");
    INDICE($V.$N$122:$N$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
    SE($V.$Q$5="Italiano";"NON DISPONIBILE";"NOT AVAILABLE")
)


In L126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120=TESTO(ANNO(OGGI()-1);"@");
    INDICE($V.$Q$122:$Q$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
    SE($V.$Q$5="Italiano";"NON DISPONIBILE";"NOT AVAILABLE")
)


Fai test
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina

Re: Trova mese in data e inserisci specifica cella

Messaggioda sandro merlino » martedì 19 giugno 2018, 21:20

Ciao unlucky83
Ti informo che la formula funziona perfettamente per quello che ti avevo chiesto ma in realtà non avevo realizzato 2 cose e per questo ti chiedo un ulteriore sforza prima di chiudere l'argomento.
La prima cosa è questa:
Nel foglio V le formule che si trovano in H, K, N, Q da 122 a 1222 funzionavano bene e facevano le somme dall'inizio del mese a oggi (cioè considerando oggi come esempio, i primi 19 giorni del mese). Alla fine del mese lasciavano il totale. Se il mese non è ancora arrivivato il risultato è cella vuota. Trovi esempio in cella U622. Da quando è stato formattata la colonna E in data non funziona più. Mi aiuteresti a fargli fare le somme?
La seconda cosa è questa:
Nel foglio DM se metto come data il primo giorno dell'anno funziona perfettamente anche con le lingue in H126, I126, K126, L126
Per il primo giorno di ogni mese funziona perfettamente perchè mi considera la somma del mese precedente in H126, I126, K126, L126
Il problema che non ti avevo detto perchè non analizzato è dal secondo giorno fino all'ultimo di ogni mese perchè la formula che trovi in U622 mi considera tutti i giorni del mese fino ad oggi mentre io oggi non lo devo considerare (sono interessato a oggi()-1). Mi aiuteresti anche qui con una modifica delle formule datemi precedentemente a levare i dati relativi ad oggi ?
Ho provato , per non disturbarti, a modificare le formule in H127, I127, K127, L127 ma non sono riuscito

Allego file

Grazie 1000
Sandro
Allegati
mese e relativa cella.ods
(158.28 KiB) Scaricato 2 volte
openoffice 4.1.1
sandro merlino
 
Messaggi: 432
Iscritto il: giovedì 12 gennaio 2012, 21:33

Re: Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » martedì 19 giugno 2018, 22:33

In H622 metti:
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE(TESTO(OGGI();"mm")<"06";"";SOMMA.SE(E625:E654;"<="&OGGI();H625:H654))

Per la seconda cosa, vuoi far sparire i valori di oggi dal foglio V o dal foglio DM? Per farli sparire dal foglio V è sufficiente mettere in H622 la formula:
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE(TESTO(OGGI();"mm")<"06";"";SOMMA.SE(E625:E654;"<="&OGGI()-1;H625:H654))

Per far sparire i valori di oggi dal foglio DM praticamente andrebbe incorporata questa modifica nelle formule del foglio DM rendendole estremamente più complicate.
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina

Re: Trova mese in data e inserisci specifica cella

Messaggioda sandro merlino » mercoledì 20 giugno 2018, 7:57

Ciao unlucky83
Per quanto riguarda le formule date sono perfette

Per quanto riguarda l'ultima domanda devo levare i valori dal foglio DM. Cioè se i giorni sono da 2 a 31 dovrei sottrarre da H,K,N,Q da 122 a 1222 i valori di oggi.
Nel precedente argomento che mi hai risolto usavamo la funzione del foglio DM in H127 per trovare i valori del foglio V in H e una piccola aggiunta relativa all'anno -1
Non è possibile modificare quella funzione e sottrarla ?



Grazie 1000

Sandro
openoffice 4.1.1
sandro merlino
 
Messaggi: 432
Iscritto il: giovedì 12 gennaio 2012, 21:33

Re: Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » mercoledì 20 giugno 2018, 8:32

Si è possibile, ma appunto, ad occhio dovrebbe estendersi del doppio la formula. Questo pom ti scrivo le nuove formule
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina

Re: Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » mercoledì 20 giugno 2018, 12:42

In H126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120<>TESTO(ANNO(OGGI()-1);"@");
    SE(Giorno(OGGI())=1;
       INDICE($V.$N$122:$N$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$N$122:$N$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$N$125:$N$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      );
    SE(Giorno(OGGI())=1;
       INDICE($V.$H$122:$H$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$H$122:$H$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$H$125:$H$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      )
)

In I126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120<>TESTO(ANNO(OGGI()-1);"@");
    SE(Giorno(OGGI())=1;
       INDICE($V.$Q$122:$Q$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$Q$122:$Q$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$Q$125:$Q$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      );
    SE(Giorno(OGGI())=1;
       INDICE($V.$K$122:$K$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$K$122:$K$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$K$125:$K$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      )
)

In K126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120=TESTO(ANNO(OGGI()-1);"@");
    SE(Giorno(OGGI())=1;
       INDICE($V.$N$122:$N$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$N$122:$N$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$N$125:$N$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      );
    SE($V.$Q$5="Italiano";"NON DISPONIBILE";"NOT AVAILABLE")
)

In L126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120=TESTO(ANNO(OGGI()-1);"@");
SE(Giorno(OGGI())=1;
       INDICE($V.$Q$122:$Q$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$Q$122:$Q$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$Q$125:$Q$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      );
    SE($V.$Q$5="Italiano";"NON DISPONIBILE";"NOT AVAILABLE")
)

Fai test, soprattutto con i 29/2 degli anni bisestili e 1/3, oltre ai 28/02. Controlla gli anni 2017, 2016, 2015
Allegati
mese e relativa cella2.ods
(143.53 KiB) Scaricato 2 volte
Ultima modifica di unlucky83 il giovedì 21 giugno 2018, 20:48, modificato 2 volte in totale.
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina

Re: Trova mese in data e inserisci specifica cella

Messaggioda sandro merlino » giovedì 21 giugno 2018, 9:00

Ciao unlucky83,
Mi controlleresti in queste 2 occasioni.
La prima è quando mettiamo la data all' 1/1/2018. In H126 e I126 le celle sono vuote forse perchè gennaio è inferiore a dicembre e quindi è vuota. Se possibile la cosa che mi è
venuta in mente ora è che invece di prendere la qello nelle celle N1222 e Q1222 mi ha la somma da 1225 a 1255. Che ne dici ? La mia è solo supposizione che aspetta tua verifica.
La seconda è quando considero 1/3/2017 dove il calcolo dell'anno bisestile 2016 si ferma a 28 giorni ma è dovuto al fatto
che nel foglio V la vormula di N e V non considera il 29 giorno

Grazie 1000

Sandro
openoffice 4.1.1
sandro merlino
 
Messaggi: 432
Iscritto il: giovedì 12 gennaio 2012, 21:33

Re: Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » giovedì 21 giugno 2018, 20:39

Per la prima cosa occorre modificare le prime due formule
In DM.H126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120<>TESTO(ANNO(OGGI()-1);"@");
    SOMMA($V.N1225:N1255);
    SE(Giorno(OGGI())=1;
       INDICE($V.$H$122:$H$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$H$122:$H$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$H$125:$H$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      )
)

In DM.I126
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE($V.$L$120<>TESTO(ANNO(OGGI()-1);"@");
    SOMMA($V.Q1225:Q1255);
    SE(Giorno(OGGI())=1;
       INDICE($V.$K$122:$K$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3);
       INDICE($V.$K$122:$K$1255;CONFRONTA(DATA(ANNO(OGGI());MESE(OGGI()-1);1);$V.$E$122:$E$1255;0)-3)-
       INDICE($V.$K$125:$K$1255;CONFRONTA(OGGI();$V.$E$125:$E$1255;0))
      )
)


Per la seconda cosa, dato che il problema si pone solo a febbraio modifica solo le due celle di foglio V relative a febbraio
In V.N22
Codice: Seleziona tutto   Espandi visualeStringi visuale

=SE(TESTO(OGGI();"mm")<"02";"";SOMMA.SE($E225:$E255;"<="&OGGI();N225:N255)+SE(E(Giorno(OGGI())=1;Giorno((DATA(ANNO(OGGI())-1;MESE(OGGI());1)-1))=29);N253;0))

In V.Q22
Codice: Seleziona tutto   Espandi visualeStringi visuale

=SE(TESTO(OGGI();"mm")<"02";"";SOMMA.SE($E225:$E255;"<="&OGGI();Q225:Q255)+SE(E(Giorno(OGGI())=1;Giorno((DATA(ANNO(OGGI())-1;MESE(OGGI());1)-1))=29);Q253;0))

Fai test
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina

Re: Trova mese in data e inserisci specifica cella

Messaggioda sandro merlino » venerdì 22 giugno 2018, 18:00

Ciao unlucky83
Direi che siamo quasi arriati alla conclusione. Tutto torna. Ho provato le formule ma ti volevo chiedere alcune conferme.
In V.N222 la formula la posso modificare:
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE(TESTO(OGGI();"mm")<"02";"";SOMMA.SE($E225:$E252;"<="&OGGI();N225:N252)+SE(E(Giorno(OGGI())=1;Giorno((DATA(ANNO(OGGI())-1;MESE(OGGI());1)-1))=29);N253;0))

In V.Q222 la formula la posso modificare:
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE(TESTO(OGGI();"mm")<"02";"";SOMMA.SE($E225:$E252;"<="&OGGI();Q225:Q252)+SE(E(Giorno(OGGI())=1;Giorno((DATA(ANNO(OGGI())-1;MESE(OGGI());1)-1))=29);Q253;0))

Ho ridotto i parametri da 255 a 252. Mi serve che in caso di errore di distrazione il valore in 253 venga sommato solo per anno bisestile.

Ti chiederei la cortesia se fosse possibile per te farmelo anche per l'anno corrente
in V.H222
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE(TESTO(OGGI();"mm")<"02";"";SOMMA.SE($E225:$E255;"<="&OGGI();H225:H255))
.
e V.K222.
Codice: Seleziona tutto   Espandi visualeStringi visuale
=SE(TESTO(OGGI();"mm")<"02";"";SOMMA.SE($E225:$E255;"<="&OGGI();K225:K255))

Le formule girano perfettamente ma ci può stare l'errore. Conosco i miei polli.

Per quanto riguarda il foglio DM posso modificare in H126, I126, K126, L126 i parametri da 122-1255 a 125-1255

Grazie 1000

Sandro
openoffice 4.1.1
sandro merlino
 
Messaggi: 432
Iscritto il: giovedì 12 gennaio 2012, 21:33

Re: Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » venerdì 22 giugno 2018, 18:29

Perchè con la formula che ti avevo suggerito io, se riempi il campo n253 anche con l’anno non bisestile, sbaglia a calcolarti il valore?
Fai le prove con le tue formule e vedi se tutto torna :-)

Per quanto riguarda il foglio DM, se cambi 122 in 125 vedrai che le formule non funzionano più, perché la somma di gennaio sta al rigo 122
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina

Re: Trova mese in data e inserisci specifica cella

Messaggioda sandro merlino » venerdì 22 giugno 2018, 19:17

Ciao unlucky83,
Come vedi prima di fare ca....e preferisco chiedere anche se le mie domande sembrano stupide.
Mi fido cecamente di quello che dici
Dichiaro chiuso l'argomento

Al prossimo problema che sicuramente verrà presto sempre su questo stampo del giorno prima che non posso risolvere.
Ora mi dedico a quello che conosco

Grazie 1000

Sandro
openoffice 4.1.1
sandro merlino
 
Messaggi: 432
Iscritto il: giovedì 12 gennaio 2012, 21:33

Re: [RISOLTO]Trova mese in data e inserisci specifica cella

Messaggioda unlucky83 » venerdì 22 giugno 2018, 23:54

Non si tratta di fidarsi ciecamente. Prova a inserire valori all'ipotetico 29 febbraio e al 30 febbraio e verifica tu stesso che questi inserimenti errati non influiscono sulle somme del mese e sui valori del foglio DM. :)
Ci sentiamo sulla prossima discussione se questa è chiusa. Buona serata
LibO5.1.6.2-Ubuntu 16.04.2 32-bit
-
Se risolvi:
1. Condividi la soluzione qui con noi
2. Metti [Risolto] al titolo del primo messaggio
Avatar utente
unlucky83
Volontario
Volontario
 
Messaggi: 1789
Iscritto il: lunedì 7 gennaio 2013, 2:23
Località: Latina


Torna a Calc

Chi c’è in linea

Visitano il forum: Nessuno e 11 ospiti